***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Nov 08, 2017                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.SUBCKT  PJE8402  D  G  S
Rg     G    1t    1m
M1      2    1    3    3    DMOS    L=1u   W=1u
.model dmos nmos ( 
+vto = {0.729*((8e-3*(temp-25))+1)}
+kp = {3.855*((3e-2*(temp-25))+1)}
+rb = 5.519e-2
+theta = 0.2  
+tnom = 25
+vmax = 0 
+level = 3)   
Cgs	1t	3	50p	ic = 0
Rd	D	4	1e-3	tc = 0.02
Dds	3	4	dds
Gds  D  S  value = {0.0043*(temp-25)*limit((v(G, S)-0.75),0,2.5)*limit(v(D,S),0,1)}
.model dds d( bv = 22  ibv = 0.25e-6  tbv1 = 1.2e-3  m=0.36  cjo=32p  vj=0.8
+is = 3.645e-11
+ n = 1.312	
+rs = 1.542)
e1	1 3 table { v(1t, S) } 
+ ((0, 0)
+  (1.00, 0.85)
+  (1.25, 1.05)
+  (1.50, 1.35)
+  (1.70, 1.60)
+  (1.75, 1.74)
+  (1.80, 1.75)
+  (2.00, 2.01)
+  (2.25, 2.22)
+  (2.50, 2.45)
+  (3.00, 2.88)
+  (3.50, 3.25)
+  (4.00, 3.50)
+  (4.50, 3.80)
+  (5.00, 4.00)
+  (8.00, 4.50)) 
dbody   3   D    dbody
.model   dbody    d(
+is = 3.645e-11
+ n = 1.312	
+rs = 5.242
+tt = 100n	
+vj = 0.8	
+eg = 1 )
ra      4    2    5e-3  tc = 0.025
rs      3    5    1e-3
ls      5    S   0.0001n
m2     1t    8    6    6   inter
e2      8    6    4    1t   2
.model	inter	nmos( vto = 0  kp = 10  level = 1 ) 
cgdmax  7    4    10p ic = 0
rcgd    7    4    10meg
dgd     6    4    dgd
rdgd    4    6    10meg
.model     dgd    d( m = 0.3   cjo = 68p   vj = 0.4 )
m3      7    9    1t    1t   inter
e3      9    1t    4    1t   -2
.ends
*$
